<%

Dim NL
NL = Chr(13) + Chr(10)

Initialise

Sub Initialise
	OpenDatabaseCommon
End Sub

Sub ShowSitemapHeader
	OpenQueryCommon("SELECT * FROM sitemap WHERE SiteName = 'HEADER'")
	Response.Write(NB(GetQueryValue("Description")))
	CloseQueryCommon
End Sub

Sub ShowGroupList
	Dim LGroupName, LAtFirst
  ' (SS,25/4/12) added AND Enabled  to following to not show those have Enabled unticked
	OpenQueryCommon("SELECT sitemapgroups.GroupName FROM sitemapgroups INNER JOIN sitemap ON sitemap.GroupName = sitemapgroups.GroupName WHERE SiteName <> 'HEADER' AND Enabled GROUP BY GroupName ORDER BY sitemapgroups.SortOrder, GroupName")
	LAtFirst = True
	Do While Not EndOfQuery
		If Not LAtFirst Then Response.Write(", ")
		LGroupName = GetQueryValue("GroupName")
		Response.Write("<a href=""#" & HTMLEncode(LGroupName) & """>" & HTMLEncode(LGroupName) & "</a>")
		NextQueryRecord
		LAtFirst = False		
	Loop
	CloseQueryCommon
End Sub

Sub ShowMainList(AAddHalfway, AHalfwayHTML)
	Dim LSQL, LGroupName, LPrevGroupName, LAtFirst, LRecordCount, LCount, LAddHalfway, LDescription
  ' (SS,25/4/12) added AND Enabled  to following to not show those have Enabled unticked
	LSQL = "SELECT sitemap.* FROM sitemap INNER JOIN sitemapgroups ON sitemapgroups.GroupName = sitemap.GroupName WHERE SiteName <> 'HEADER' AND Enabled ORDER BY sitemapgroups.SortOrder, GroupName, sitemap.SortOrder, SiteName"
	OpenQueryCommon(LSQL)
	LRecordCount = 0
	Do While Not EndOfQuery
		LRecordCount = LRecordCount + 1
		NextQueryRecord	
	Loop
	CloseQueryCommon		
	LAtFirst = True
	LPrevGroupName = ""
	LCount = 0
	LAddHalfway = AAddHalfway
	OpenQueryCommon(LSQL)
	Do While Not EndOfQuery
		LCount = LCount + 1
		LGroupName = GetQueryValue("GroupName")
		If LGroupName <> LPrevGroupName Then
			' if halfway and enabled then output the halfway html (used to separate into 2 columns) 
			If LAddHalfway And LCount > (LRecordCount / 2) Then
				Response.Write(AHalfwayHTML) & NL
				LAddHalfway = False ' to only do once
				LAtFirst = True ' i.e. first in new column
			End If
			If Not LAtFirst Then Response.Write("<br>") ' extra break
			Response.Write("<p><b><a name=""" & HTMLEncode(LGroupName) & """>" & HTMLEncode(LGroupName) & "</a></b></p>" & NL)
			LPrevGroupName = LGroupName
		End If
		Response.Write("<a href=""" & GetQueryValue("SiteURL") & """>" & HTMLEncode(GetQueryValue("SiteName")) & "</a><br>" & NL)
		LDescription = TrimAll(NB(GetQueryValue("Description")))
		If Len(LDescription) > 1 And Right(LDescription, 1) <> "." Then LDescription = LDescription + "."
		Response.Write(ReplaceNewlinesWithBR(HTMLEncode(LDescription) & NL))
		Response.Write("<br>" & NL & NL)
		NextQueryRecord
		LAtFirst = False		
	Loop
	CloseQueryCommon
End Sub

Sub Finalise
	CloseDatabaseCommon
End Sub

%>