<%

Dim strCommand, gbAuthenticated, gsAccessRights, gnAccessLevel
Dim gsUserID, gsSessionID, gnAuditID

strCommand = Request.QueryString("cmd")
If strCommand = "" then strCommand = Request.Form("cmd")


If Not Session("Authenticated") Then

  Dim sUserID, sPassword

  sUserID = Request.Form("userid")
  sPassword = Request.Form("password")

  If strCommand = "Enter" And sUserID <> "" And sPassword <> "" Then
    gsAccessRights = GetAccessRights(sUserID, sPassword)
    If gsAccessRights <> "" Then
      Session("Authenticated") = True
      Session("AccessRights") = gsAccessRights
      Session("AccessLevel") = GetAccessLevel(gsAccessRights)
      Session("UserName") = sUserID   ' (SS,17/1/2002)

      RecordLog "LOGONOFF", ""

      'DoAfterLogonRoutines

    End If
  End If

  If Not Session("Authenticated") Then
%>
<form name="login" action="main.asp" method="post">
<table border="0" cellpadding="0" cellspacing="0" class="title">
<tr>
<td valign="top"><Strong><font size="4">Login</font></Strong></td>
<td>&nbsp;</td>
<td>&nbsp;</td>
<td rowspan="5">&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;<img src="logo.jpg"></td>
</tr>
<tr>
<td nowrap>User ID:&nbsp;</td>
<td><input type="text" name="userid" size="15"></td>
<td></td>

</tr>

<tr>
<td nowrap>Password:&nbsp;</td>
<td><input type="password" name="password" size="15"></td>
<td>&nbsp;<input type="submit" name="cmd" value="Enter"></td>
</tr>
<tr><td>&nbsp;</td></tr>
<tr><td>&nbsp;</td></tr>
<tr><td>&nbsp;</td></tr>
</table>
</form>
<%
    gsFocusForm = "login"
    gsFocusField = "userid"
  End If

End If

gbAuthenticated = Session("Authenticated")
gsAccessRights = Session("AccessRights")
gnAccessLevel = Session("AccessLevel")
gsUserID = Session("UserName")
gsSessionID = Session.SessionID

' (SS,22/10/15)
Const ACCESS_LEVEL_REPORT = 0
Const ACCESS_LEVEL_VIEW = 1
Const ACCESS_LEVEL_UPDATE = 5
Const ACCESS_LEVEL_ADMIN = 9

' (SS,22/10/15)
Function CanUpdate
  CanUpdate = gnAccessLevel >= ACCESS_LEVEL_UPDATE
End Function

' (SS,23/10/15)
Function IsAdmin
  IsAdmin = gnAccessLevel >= ACCESS_LEVEL_ADMIN
End Function

%>