<%
'This code is copyright (c) Internet Business Solutions SL, all rights reserved.
'The contents of this file are protect under law as the intellectual property
'of Internet Business Solutions SL. Any use, reproduction, disclosure or copying
'of any kind without the express and written permission of Internet Business 
'Solutions SL is forbidden.
'Author: Vince Reid, vince@virtualred.net
Sub DoSendEmail(seTo,seFrom,seSubject,seBody)
	Dim mailissent
	mailissent = false
	on error resume next
	err.number = 0
	' First check for CDONTS.
	if mailhost = "your.mailserver.com" OR mailhost = "" then
		Set EmailObj = Server.CreateObject("CDO.Message")
		if err.number = 0 then
			EmailObj.From = Chr(34) & seFrom & Chr(34) & Chr(60) & seFrom & Chr(62)
			EmailObj.ReplyTo = Chr(34) & seFrom & Chr(34) & Chr(60) & seFrom & Chr(62)
			EmailObj.Subject = seSubject
			EmailObj.Fields.Update
			EmailObj.TextBody = seBody
			EmailObj.To = Chr(34) & seTo & Chr(34) & " <" & seTo & ">"
			EmailObj.Send
			mailissent = true
		end if
		if NOT mailissent then
			err.number = 0
			Set EmailObj = Server.CreateObject("CDONTS.NewMail")
			if err.number = 0 then
				EmailObj.MailFormat = 0
				EmailObj.To = seTo
				EmailObj.From = seFrom
				EmailObj.Subject = seSubject
				EmailObj.Body = seBody
				EmailObj.Send
				mailissent = true
			end if
		end if
	end if
	if NOT mailissent AND mailhost <> "your.mailserver.com" AND mailhost <> "" then
		err.number = 0
		' Check for ASP Mail
		Set EmailObj = Server.CreateObject("Persits.MailSender")
		if err.number = 0 then
			EmailObj.Host = mailhost
			EmailObj.AddAddress seTo
			EmailObj.From = seFrom
			EmailObj.FromName = seFrom
			EmailObj.Subject = seSubject
			EmailObj.Body = seBody
			EmailObj.Send
			mailissent = true
		end if
	end if
	if NOT mailissent AND mailhost <> "your.mailserver.com" AND mailhost <> "" then
		err.number = 0
		' Check for ASP Mail
		Set EmailObj = Server.CreateObject("SMTPsvg.Mailer")
		if err.number = 0 then
			EmailObj.RemoteHost = mailhost
			EmailObj.AddRecipient seTo, seTo
			EmailObj.FromAddress = seFrom
			EmailObj.Subject = seSubject
			EmailObj.BodyText = seBody
			EmailObj.SendMail
			mailissent = true
		end if
	end if
	if NOT mailissent AND mailhost <> "your.mailserver.com" AND mailhost <> "" then
		err.number = 0
		' Check for Dimac JMail
		Set EmailObj = Server.CreateObject("JMail.SMTPMail")
		if err.number = 0 then
			EmailObj.silent = true
			EmailObj.Logging = true
			EmailObj.ServerAddress = mailhost
			EmailObj.AddRecipient seTo
			EmailObj.Sender = seFrom
			EmailObj.Subject = seSubject
			EmailObj.Body = seBody
			EmailObj.Execute
			mailissent = true
		end if
	end if
	Set EmailObj = nothing
	on error goto 0
End Sub
%>