<%
' --- START OF MESSAGE TEMPLATES --- '
' (SS,26/08/14) modified for Bootstrap
' (SS,02/10/14) added text function GetCheckoutMessage
' (SS,09/10/14) updated Sub ShowBasketInfo to show delivery info
' (SS,26/08/15) special version of Express Music
' (SS,11/03/16) added Function GetMessage for compatibility with latest inc-template-checkout.asp
' (SS,13/12/16) change to Function GetCheckoutMessage
' (SS,05/10/20) for compatibility with latest common templates, added new version of Sub ShowPageTitle with 3 parameters and added Sub ShowPageBreadcrumb, Function ProperPageName
' (SS,10/06/21) added CustomShowHolidayNotice to Sub ShowBasketInfo
' (SS,24/11/21) added DeliveryWillCollect message to GetMessage
' (SS,08/07/22) function GetCheckoutMessager, replaced (Mon-Fri) with (Tue-Fri)
' (SS,10/03/23) ending <b> tag correction to Sub ShowMessage

' (SS,09/06/11) changed to use new div version
' (SS,18/08/15) added page-title class to add a top margin
' (SS,05/10/20) old version, renamed, can be removed
Sub ShowPageTitleOld(ATitle)
%>
  <div class="panel panel-default page-title">
    <div class="panel-heading"><%=ATitle%></div>
  </div>
<%
End Sub


' (SS,5/12/19) added breadcrumb to be used at start of every page, relative to home page, also added HTMLEncode
Sub ShowPageBreadcrumb(APageName)
%> 
  <ul class="breadcrumb">
    <li><a href="/">Home</a></li>
    <li><%=HTMLEncode(ProperPageName(APageName))%></li>
  </ul>
<%
End Sub

' (SS,09/06/11) changed to use new div version
' (SS,5/12/19) new version which shows a breadcrumb, previously this was a top of a panel which wasn't ideal
' also added an extra (APageName) parameter to allow page name to be different, i.e. calls ShowPageBreadcrumb above
' had to change all calls to ShowPageTitle to added the extra parameter, added a 3rd parameter for additional options, not used currently
' if APageName is blank then it assume same value as ATitle
Sub ShowPageTitle(APageName, ATitle, AOptions)
  Dim LTitle
  LTitle = ATitle
  If LTitle = "" Then LTitle = ProperPageName(APageName)
  ShowPageBreadcrumb APageName
  
  ' (SS,5/10/20) for pages repairs and storecoventry, they already have a H1 tag hardcoded so don't show following
  If APageName <> "repairs" And APageName <> "storecoventry" Then
%>
  <h1><%=HTMLEncode(LTitle)%></h1>
<%  
  End If
End Sub

' (SS,5/10/20) converts the lowercase page name to proper one, perhaps in future have a separate field in settings for this
Function ProperPageName(APageName)
  Dim LResult
  Select Case APageName
    Case "about"
      LResult = "About Us"
    Case "deliveryinfo"
      LResult = "Delivery Info" 
    Case "howtoorder"
      LResult = "How to Order"
    Case "customerinfo"
      LResult = "Customer Info" 
    Case "privacy"
      LResult = "Privacy"
    Case "links"
      LResult = "Links"
    Case "faq"
      LResult = "FAQ" 
    Case "coronavirus"
      LResult = "Coronavirus"
    Case "repairs"
      LResult = "Repairs"
    Case "storecoventry"
      LResult = "Coventry Store"
    ' (SS,20/7/22) Coventry Store replaced with Visit Us
    Case "visitus"
      LResult = "Visit Us"      
    Case Else
      LResult = APageName
  End Select
  
  ProperPageName = LResult
End Function

' (SS,17/2/05)
' (SS,10/3/23) corrected ending <b> tag to </b> was <b>
Sub ShowMessage(AMessage)
%>
<b><%=AMessage%></b><br>
<%
End Sub

Sub ShowSearchNotFound
%>
<table width="100%" border="0" cellspacing="0" cellpadding="0">
<tr>
<td width="1%">&nbsp;&nbsp;&nbsp;</td>
<td width="99%" valign="top">
If there is an item in particular you are looking for, but can&#8217;t find it on this site, please <a href="products.asp?page=contact"><font color="#990000">contact us</font></a> and we will try and find it for you.<br>    <br>
</td>
</tr>
</table>
<%
End Sub

' (SS,23/7/10) added message as requested
Function GetOrderConfirmationExtraMessage
  GetOrderConfirmationExtraMessage = "You will be sent an email on day of dispatch with your tracking information.<br><br>Any queries regarding this order please email <a href=""mailto:" & GetStoreEmail & """>" & GetStoreEmail & "</a>"
End Function

Function EmailOrderConfirmationFooter
  Dim NL
  NL = Chr(13) + Chr(10)
  EmailOrderConfirmationFooter = ""
End Function

' (SS,17/7/07) message shown next to country combo to ensure user selects correct country
Function GetImportantCountryMessage
  GetImportantCountryMessage = ""
End Function

Function GetPaymentExtraMessage
  GetPaymentExtraMessage = ""
End Function

' (SS,11/12/07) used to add extra note before or after existing note
' (SS,16/3/12) removed
'Function GetBasketNote(AExistingNote)
'  Dim LNewNote
'  LNewNote = ""
'  GetBasketNote = AExistingNote + LNewNote
'End Function

' (SS,16/3/12) this replaces above GetBasketNote, total weight is passed here from ShowBasketFooter (inc-template-messages.asp)
' (SS,9/9/14) removed <p>We hope you enjoy your visit to ..=GetStoreName..'s website.</p>
' (SS,9/10/14) added delivery info, also added space between total weight and units
' (SS,10/10/14) removed "<p>If you have any comments or suggestions we would be happy to hear from you.</p>"
Sub ShowBasketInfo(ATotalWeight)
%>    
    <p>Total weight of this order: <b><%=ATotalWeight & " " & GetWeightUnits%></b></p>    
    
    <p><b><%=GetDeliveryInfo%></b></p>

<%

  ' (SS,10/6/21) show the holiday message for the basket
  CustomShowHolidayNotice "B", 0
End Sub


' (SS,11/12/07) for checkout just before making payment
' (SS,23/7/10) added message as requested
' (SS,13/12/16) removed the text "Orders received by 12pm will be despatched for next working day delivery (Mon-Fri) unless otherwise stated."
' (SS,08/07/22) replaced (Mon-Fri) with (Tue-Fri)
Function GetCheckoutMessage
  ' GetCheckoutMessage = "Orders received by 12pm will be despatched for next working day delivery (Mon-Fri) unless otherwise stated. We can only deliver goods to the same address to which the credit/debit card used to pay for the goods is registered."
  ' (SS,13/12/16) replaced above with following
  ' (SS,08/07/22) replaced (Mon-Fri) with (Tue-Fri)
  GetCheckoutMessage = "Orders received by 12pm will be despatched for next working day delivery (Tue-Fri) unless otherwise stated."  
End Function

' (SS,3/11/16) add following multipurpose message return routine, overcomes having to create a new function for each new message and having to add it to each site for full compatibility
' (SS,24/11/21) added DeliveryWillCollect message shown on delivery address section of confirmation email
Function GetMessage(AName)
  Dim Result
  If AName = "DeliveryWillCollect" Then
    Result = "We will contact you when your order is ready to collect."
  Else
    Result = ""
  End If
  GetMessage = Result 
End Function

' --- END OF MESSAGE TEMPLATES --- '
%>