rem SS, 13/10/08 full backup for new 1and1 server to 1and1 backup ftp server
rem SS, 25/09/09 improved log to add date/time and dir of FTP folder, also send today's log as email

d:
cd d:\bin\fullbackup
rem create the backup file
echo Start ntbackup>logtoday.txt
date /t >>logtoday.txt
time /t >>logtoday.txt
C:\WINDOWS\system32\ntbackup.exe backup "@d:\bin\fullbackup\fullbackup.bks" /n "MediaName - Fullbackup" /d "SetDesc - Fullbackup" /v:no /r:no /rs:no /hc:off /m normal /j "fullbackup" /l:s /f "D:\Backups\fullbackup.bkf"

rem --- build the FTP operations file
echo bak3418515>ftpop.txt
echo 3wwVvzVd>>ftpop.txt
echo binary>>ftpop.txt
rem following deletes backup file from 7 days ago
cmddate -7 delete backup#.bkf>>ftpop.txt
rem following uploads todays backup file
cmddate 0 put d:\backups\fullbackup.bkf>>ftpop.txt
rem --- rename the backup file with today's date at the end
cmddate 0 rename fullbackup.bkf backup#.bkf>>ftpop.txt
echo dir>>ftpop.txt
echo quit>>ftpop.txt

rem --- FTP the file to the 1and1 backup ftp server, and the various FTP commands
rem ftp -s:ftpop.txt backup339.onlinehome-server.info>>ftplog.txt
rem (SS,25/9/09) replaced above with following

echo Start FTP>>logtoday.txt
date /t >>logtoday.txt
time /t >>logtoday.txt
ftp -s:ftpop.txt backup339.onlinehome-server.info>>logtoday.txt
echo Finish>>logtoday.txt
date /t >>logtoday.txt
time /t >>logtoday.txt

echo. >>log.txt
type logtoday.txt >>log.txt
echo ------------------------------------------------------------------------------->>log.txt

:sendemail

itpSendEmail low surinder@itpartnership.com fullbackup@itpartnership.com "Full Backup Results" logtoday.txt

rem check for success
rem check if certain phrases exist, error if they do
find /i "550 RNFR command failed." logtoday.txt
if ERRORLEVEL 1 goto ok1 
goto error1
:ok1
find /i "451 Failure writing to local file." logtoday.txt
if ERRORLEVEL 1 goto ok2
goto error1
:ok2
find /i "553 Could not create file." logtoday.txt
if ERRORLEVEL 1 goto ok3
goto error1
:ok3

rem check if certain phrases don't exist, error if they don't

find /i "230 Login successful." logtoday.txt
if ERRORLEVEL 1 goto error1

find /i "226 File receive OK." logtoday.txt
if ERRORLEVEL 1 goto error1

find /i "250 Rename successful." logtoday.txt
if ERRORLEVEL 1 goto error1

rem success if this point reached
goto end

:error1
itpSendEmail high purchases@itpartnership.com fullbackup@itpartnership.com "ITP ALERT!!! Full Backup FTP Failure" logtoday.txt

:end